summaryrefslogtreecommitdiffstats
path: root/lib/Jaos/WebApp/Route/ParamConstraint.pm
blob: c5248335e9c06d8219cb1c34b2174e887eece120 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
package Jaos::WebApp::Route::ParamConstraint;
use strict;
use warnings;

sub register
{
  my ($class, $app) = @_;

  $app->add_route_hook(
    constraint => sub {
      my ($route, $ctx, $arguments) = @_;

      return unless ref($arguments) eq 'HASH';

      for my $key ( keys %$arguments ) {
        my $pattern = $arguments->{$key};
        if (my $value = $ctx->req->param($key)) {
          $ctx->log->debug("Checking $key($value) against $pattern");
          if (ref $pattern eq 'Regexp') {
            return $value =~ $pattern;
          } else {
            return $value eq $pattern;
          }
        }
      }
      return;
    }
  );
}

=head1 NAME

Jaos::WebApp::Route::ParamConstraint - Adds a parameter route constraint

=head1 SYNOPSIS

 package MyApp;
 use base qw/Jaos::WebApp/;
 sub startup
 {
   my $app = shift;
   $app->load_plugin('Jaos::WebApp::Route::ParamConstraint');
   $app->connect('/user/:id', constraint => { id => qr/^\d+$/ });
 }
 1;

=head1 DESCRIPTION

This adds a route option called "constraint" that allows matching parameters against specific values or regular expressions.

=head1 METHODS

=head2 register

Called by the L<Jaos::WebApp> plugin loader.

=head1 AUTHOR

Jason Woodward <woodwardj@jaos.org>

=head1 LICENSE

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=cut

1;